Terjemahan disediakan oleh mesin penerjemah. Jika konten terjemahan yang diberikan bertentangan dengan versi bahasa Inggris aslinya, utamakan versi bahasa Inggris.

# Pantau penggunaan penyimpanan indeks
<a name="index-usage-monitoring"></a>

Log penggunaan indeks memberikan visibilitas tentang cara penyimpanan indeks Amazon Quick dikonsumsi di seluruh basis pengetahuan dan Spasi, termasuk unggahan file. Anda dapat menggunakan log ini untuk melacak tren pertumbuhan, mengidentifikasi sumber terbesar, mendeteksi lonjakan tak terduga, dan merencanakan kapasitas.

Sebelum Anda menanyakan data penggunaan indeks, Anda harus mengonfigurasi `INDEX_USAGE_LOGS` pengiriman. Untuk petunjuk tentang pengaturan pengiriman, lihat[Memantau Amazon Penggunaan Cepat menggunakan CloudWatch Log](monitoring-quicksuite-chat-feedback-cloudwatch.md).

## Skema log
<a name="index-usage-monitoring-schema"></a>

Setiap peristiwa log penggunaan indeks mencakup bidang umum yang dibagikan di semua jenis log Cepat Amazon, seperti`resource_arn`,`event_timestamp`,`log_type`,`account_id`, dan`user_arn`. Acara ini juga mencakup bidang khusus indeks berikut:


**Kolom log penggunaan indeks**  

| Bidang | Tipe | Deskripsi | 
| --- | --- | --- | 
| consumed\_index\_size | Bilangan Bulat | Ukuran total (dalam byte) yang dikonsumsi oleh seluruh indeks. Ini adalah total otoritatif. | 
| source\_type | String | SPACE atau KB. | 
| source\_name | String | Tampilkan nama Space atau basis pengetahuan. | 
| source\_arn | String | ARN penuh dari sumbernya. | 
| consumed\_source\_size | Bilangan Bulat | Ukuran (dalam byte) dikonsumsi oleh sumber individu ini. | 
| consumed\_source\_doc\_count | Bilangan Bulat | Jumlah dokumen dalam sumber ini. | 

**catatan**  
Acara dipublikasikan per sumber tentang perubahan. Tidak semua sumber memancarkan peristiwa setiap hari. Untuk merekonstruksi status saat ini, gunakan peristiwa terbaru per. `source_arn`

## CloudWatch Kueri Wawasan Log
<a name="index-usage-monitoring-queries"></a>

Kueri Wawasan CloudWatch Log berikut membantu Anda menganalisis data penggunaan indeks. Semua kueri menggunakan pola `stats latest(field) by source_arn` untuk mendapatkan status terbaru per sumber. Kueri kemudian digabungkan sesuai kebutuhan. Ganti {{YOUR\_LOG\_GROUP}} dengan nama grup log Anda.

### Ukuran berdasarkan jenis sumber (basis pengetahuan dibandingkan dengan Spasi)
<a name="index-usage-query-kb-vs-spaces"></a>

Menunjukkan pemisahan ukuran total antara basis pengetahuan dan Spasi.

```
fields @timestamp, source_type, source_arn, consumed_source_size
| stats latest(consumed_source_size) as latest_size, latest(source_type) as type by source_arn
| stats sum(latest_size) as total_size by type
```

### Ukuran indeks total dari waktu ke waktu
<a name="index-usage-query-total-over-time"></a>

Menunjukkan tren ukuran indeks dengan menggunakan `consumed_index_size` bidang.

```
fields @timestamp, consumed_index_size
| stats latest(consumed_index_size) as total_index_size by bin(1d) as day
| sort day asc
```

### Basis pengetahuan teratas berdasarkan ukuran
<a name="index-usage-query-top-kb"></a>

Menunjukkan 20 basis pengetahuan teratas yang diberi peringkat berdasarkan ukuran.

```
fields @timestamp, source_type, source_arn, source_name, consumed_source_size
| filter source_type = "KB"
| stats latest(consumed_source_size) as latest_size, latest(source_name) as name by source_arn
| sort latest_size desc
| limit 20
```

### Ruang Teratas berdasarkan ukuran
<a name="index-usage-query-top-spaces"></a>

Menampilkan 20 Spaces teratas yang diberi peringkat berdasarkan ukuran.

```
fields @timestamp, source_type, source_arn, source_name, consumed_source_size
| filter source_type = "SPACE"
| stats latest(consumed_source_size) as latest_size, latest(source_name) as name by source_arn
| sort latest_size desc
| limit 20
```

### Semua sumber detail
<a name="index-usage-query-all-sources"></a>

Menampilkan status terbaru dari setiap sumber dengan ukuran, jenis, nama, jumlah dokumen, dan waktu pembaruan terakhir.

```
fields @timestamp, source_type, source_name, consumed_source_size, consumed_source_doc_count, source_arn
| stats latest(consumed_source_size) as latest_size, latest(source_type) as type, latest(source_name) as name, latest(consumed_source_doc_count) as doc_count, latest(@timestamp) as last_updated by source_arn
| sort latest_size desc
| limit 100
```

### Pengguna teratas berdasarkan ukuran total
<a name="index-usage-query-top-users"></a>

Menampilkan 20 pengguna teratas yang diberi peringkat berdasarkan ukuran sumber total di semua sumber mereka.

```
fields @timestamp, user_arn, source_arn, consumed_source_size
| parse user_arn "*:user/*/*" as @prefix, @namespace, @username
| stats latest(consumed_source_size) as latest_size, latest(@username) as user by source_arn
| stats sum(latest_size) as total_size by user
| sort total_size desc
| limit 20
```

## Buat CloudWatch dasbor
<a name="index-usage-monitoring-dashboard"></a>

Anda dapat membuat CloudWatch dasbor untuk memvisualisasikan metrik penggunaan indeks. Gunakan CloudWatch konsol untuk membuat dasbor dan menambahkan widget Wawasan Log dengan menggunakan kueri dari bagian sebelumnya.

1. Buka [konsol CloudWatch](https://console.aws.amazon.com/cloudwatch).

1. Pada panel navigasi, silakan pilih **Dasbor**.

1. Pilih **Buat dasbor** dan masukkan nama (misalnya,`IndexUsageMetrics`).

1. Tambahkan widget dengan menggunakan jenis widget **Log**. Pilih grup log penggunaan indeks Anda dan tempel kueri dari bagian sebelumnya.

**Tip**  
Gunakan visualisasi diagram lingkaran untuk rincian tipe sumber. Gunakan bagan garis untuk ukuran dari waktu ke waktu. Gunakan bagan batang untuk sumber teratas. Visualisasi tabel berfungsi dengan baik untuk kueri detail semua sumber.